* Encoding: UTF-8.

* Budeme pracovat s daty za ČR.
USE ALL.
COMPUTE filter_$=(country=5).
VARIABLE LABELS filter_$ 'country=5 (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMATS filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

*Máme 729 případů.
FREQ country.
 
* Naší závislou proměnnou bude čas užívání internetu DCtimeuse.
examine DCtimeuse
 /PLOT HISTOGRAM BOXPLOT.

* Naší nezávislou proměnnou bude SES - DPSESHH3.
FREQ DPSESHH3 .

*Jak se liší průměry DCtimeuse ve skupinách SES?.
examine DCtimeuse BY DPSESHH3
 /PLOT HISTOGRAM BOXPLOT.

MEANS TABLES=DCtimeuse BY DPSESHH3
  /CELLS=COUNT MEAN  STDDEV VAR.

GRAPH
  /LINE=MEAN(DCtimeuse) BY DPSESHH3 
  /INTERVAL CI(95.0).

*V obou chybí 10 lidí. Je to těch samých 10?. 
MVA VARIABLES=DCtimeuse DPSESHH3
  /MAXCAT=25
  /CATEGORICAL=DPSESHH3
  /TTEST PROB PERCENT=0
  /TPATTERN PERCENT=0.
*Ne není. V ANOVA tak bude jen 709.

*Předpoklady - normalita, homoskedascita.

*A samotná ANOVA.
ONEWAY DCtimeuse BY DPSESHH3
  /STATISTICS DESCRIPTIVES HOMOGENEITY
  /PLOT MEANS
  /MISSING ANALYSIS.

*Kdybychom nechtěli riskovat heteroskedascitu, můžřeme použít Welchovu korekci.
ONEWAY DCtimeuse BY DPSESHH3
  /STATISTICS DESCRIPTIVES HOMOGENEITY WELCH
  /PLOT MEANS
  /MISSING ANALYSIS.

*Můžeme reportovat, étu/omegu si musíme dopočítat.

* Kontrasty.
* Otestujme dvě hypotézy z přednášky.
*H1: Děti z rodin s nízkým SES používají internet méně často než ostatní děti.
*H2: Děti z rodin se středním SES používají internet méně často než děti z rodin s vysokým SES.
ONEWAY DCtimeuse BY DPSESHH3
  /STATISTICS DESCRIPTIVES HOMOGENEITY
  /CONTRAST .5 .5 -1
  /CONTRAST 1  -1 0
  /PLOT MEANS
  /MISSING ANALYSIS.

*Post-hoc testy?.
*Když už jsme použili kontrasty, není pro jejich použití sebemenší důvod.
*Takže jen abychom si je ukázali.
ONEWAY DCtimeuse BY DPSESHH3
  /STATISTICS DESCRIPTIVES   
  /POSTHOC = QREGW TUKEY
  /MISSING ANALYSIS.


*Porovnání s regresí.

*Dummy kódování.
RECODE DPSESHH3 (1=1) (2=0) (3=0) INTO VYS_SES_D.
RECODE DPSESHH3 (1=0) (2=1) (3=0) INTO STR_SES_D.
EXECUTE.
FREQ VYS_SES_D STR_SES_D.

*Efektové kódování.
RECODE DPSESHH3 (1=1) (2=0) (3=-1) INTO VYS_SES_E.
RECODE DPSESHH3 (1=0) (2=1) (3=-1) INTO STR_SES_E.
EXECUTE.
FREQ VYS_SES_E STR_SES_E.

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT DCtimeuse
  /METHOD=ENTER VYS_SES_D STR_SES_D.

REGRESSION
  /DESCRIPTIVES MEAN STDDEV CORR SIG N
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT DCtimeuse
  /METHOD=ENTER VYS_SES_E STR_SES_E.





*Přejděme k faktoriální anově.
*Nejprve si spočítáme one-way anovu pomocí příkazu UNIANOVA, abychom viděli, že výsledek je stejný.
UNIANOVA DCtimeuse BY DPSESHH3 
 /DESIGN = DPSESHH3 
 /PRINT = DESCRIPTIVE 
 /PLOT PROFILE (DPSESHH3) ERRORBAR = CI.

*Můžeme přidat další faktor - pohlaví.
*Máme ho, zdá se, pro všech 729 lidí, takže nám to neovlivní efektivní velikost vzorku.
FREQ QP201b.

MEANS TABLES=DCtimeuse BY QP201b
  /CELLS=COUNT MEAN  STDDEV VAR.

*Dohromady i s SES.
CROSSTABS
  /TABLES= QP201b BY DPSESHH3
  /FORMAT=AVALUE TABLES
  /CELLS=COUNT
  /COUNT ROUND CELL.

CTABLES
  /VLABELS VARIABLES=QP201b DCtimeuse DPSESHH3 DISPLAY=BOTH
  /TABLE QP201b [C] BY DCtimeuse [S][MEAN] > DPSESHH3
  /CATEGORIES VARIABLES=QP201b DPSESHH3 ORDER=A KEY=VALUE EMPTY=INCLUDE
  /CRITERIA CILEVEL=95.
*Nechci zapomenout ani na SD a N. 
CTABLES
  /VLABELS VARIABLES=QP201b DCtimeuse DPSESHH3 DISPLAY=BOTH
  /TABLE QP201b [C] BY DCtimeuse [S][COUNT MEAN STDDEV] > DPSESHH3
  /CATEGORIES VARIABLES=QP201b DPSESHH3 ORDER=A KEY=VALUE EMPTY=INCLUDE
  /CRITERIA CILEVEL=95.

*Graficky. 
GRAPH
  /LINE(MULTIPLE)=MEAN(DCtimeuse) BY DPSESHH3 BY QP201b
  /INTERVAL CI(95.0).

*Chci aspoň nakouknout na rozložení uvnitř skupin.
*To druhé BY nejde naklikat.
examine DCtimeuse BY DPSESHH3 BY QP201b
 /PLOT HISTOGRAM BOXPLOT.

* A nyní si můžeme spočítat ANOVU.
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
 /DESIGN = DPSESHH3 QP201b DPSESHH3*QP201b
 /PRINT = DESCRIPTIVE
  /PLOT PROFILE (DPSESHH3*QP201b) ERRORBAR = CI.

*Protože máme v modelu více faktorů, můžeme požádat o EMM, 
tedy _odhady_ toho, jaké by byly průměry ve skupinách podle jednoho faktoru,
kdyby v nich byly skupiny podle druhého faktoru zastoupeny stejně.
*Jsou to vlastně predikované skóry. 
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
 /DESIGN = DPSESHH3 QP201b DPSESHH3*QP201b
 /PRINT = DESCRIPTIVE
  /PLOT PROFILE (DPSESHH3*QP201b) ERRORBAR = CI
  /EMMEANS=TABLES(DPSESHH3) 
  /EMMEANS=TABLES(QP201b). 


*Je dobré vědět, že defaultní model, který zahrnuje interakci, lze změnit.
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
 /DESIGN = DPSESHH3 QP201b 
 /PRINT = DESCRIPTIVE
  /PLOT PROFILE (DPSESHH3*QP201b) ERRORBAR = CI
  /EMMEANS=TABLES(DPSESHH3) 
  /EMMEANS=TABLES(QP201b). 



* A podívejme se na kontrasty. Způsob jejich zadávání se zde liší.
* Je dobré si uvědomit, že porovnáváme průměry podle jednoho faktoru korigované 
na možný vliv ostatních faktorů Estimated Marginal Means.   
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
  /CONTRAST(DPSESHH3)=Helmert
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PRINT ETASQ DESCRIPTIVE PARAMETER
  /CRITERIA=ALPHA(.05)  
  /DESIGN=DPSESHH3 QP201b DPSESHH3*QP201b.
*Kontrast ručně.
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
  /CONTRAST(DPSESHH3)=SPECIAL ( .5 .5 -1  1   -1   0)
  /EMMEANS=TABLES(DPSESHH3) 
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PRINT ETASQ DESCRIPTIVE PARAMETER
  /CRITERIA=ALPHA(.05)  
  /DESIGN=DPSESHH3 QP201b DPSESHH3*QP201b.


*Příkaz UNIANOVA nabízí obrovské množství outputu. 
UNIANOVA DCtimeuse BY DPSESHH3 QP201b
  /CONTRAST(DPSESHH3)=Helmert
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PLOT=PROFILE(DPSESHH3*QP201b) TYPE=LINE ERRORBAR=CI MEANREFERENCE=NO YAXIS=AUTO
  /EMMEANS=TABLES(DPSESHH3) 
  /EMMEANS=TABLES(QP201b) 
  /PRINT MBP ETASQ DESCRIPTIVE PARAMETER HOMOGENEITY OPOWER
  /PLOT=SPREADLEVEL RESIDUALS
  /CRITERIA=ALPHA(.05)  
  /ROBUST=HC3     *Žádost o analogii Welchova F
  /DESIGN=DPSESHH3 QP201b DPSESHH3*QP201b.



*Nakonec ještě dvě jednotlivosti.
*Model s random faktorem.
USE ALL.
UNIANOVA DCtimeuse BY country
 /DESIGN = country
 /RANDOM = country 
 /PRINT = DESCRIPTIVE
  /PLOT PROFILE (country) ERRORBAR = CI.

 UNIANOVA DCtimeuse BY country
 /DESIGN = country
 /RANDOM = country 
 /PRINT = DESCRIPTIVE
  /EMMEANS=TABLES(country) COMPARE ADJ(SIDAK)
  /PLOT PROFILE (country) ERRORBAR = CI.

*ANCOVA.
UNIANOVA DCtimeuse BY country WITH QP204
 /DESIGN = country QP204 country*QP204
 /RANDOM = country 
 /PRINT = DESCRIPTIVE
  /PLOT PROFILE (country) ERRORBAR = CI.