;noesyfpgpphwg
;avance-version (12/01/11)
;NOESY
;2D homonuclear correlation via dipolar coupling 
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive
;water suppression using watergate sequence
;using flip-back pulse
;(use parameterset NOESYFPGPPHWG)
;
;M. Piotto, V. Saudek & V. Sklenar, J. Biomol. NMR 2, 
;   661 - 666 (1992)
;V. Sklenar, M. Piotto, R. Leppik & V. Saudek, J. Magn. Reson. A102,
;   241 -245 (1993)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"d12=20u"

#   ifdef LABEL_CN
"p22=p21*2"
#   else
#   endif /*LABEL_CN*/


"in0=inf1/2"

#   ifdef LABEL_CN
"d0=3u"
"DELTA1=d0*2+larger(p8,p22)"
#   else
"d0=in0/2-p1*2/3.1416"
#   endif /*LABEL_CN*/


"DELTA=d8-p16-d16-p29*2-8u"


1 ze

#   ifdef LABEL_CN
2 d1 do:f2 do:f3
  d12 pl2:f2 pl3:f3
#   else
2 d1
  d12
#   endif /*LABEL_CN*/

3 d12 pl1:f1
  50u UNBLKGRAD

  (p29:sp11 ph7):f1
  2u
  2u pl1:f1
  (p1 ph1)

#   ifdef LABEL_CN
  d0
  (center (p8:sp13 ph2):f2 (p22 ph2):f3 )
  d0
  (p2 ph9)
  DELTA1
  (p1 ph8)
#   else
  d0
  d0
  (p1 ph2)
#   endif /*LABEL_CN*/

  4u
  (p29:sp11 ph8):f1
  p16:gp1
  d16
  DELTA
  (p29:sp11 ph3:r):f1
  2u
  2u pl1:f1
  (p1 ph4)

  4u
  p16:gp2
  d16
  (p11:sp1 ph5:r):f1
  2u
  2u pl1:f1
  (p2 ph6)
  4u
  (p11:sp1 ph5:r):f1
  p16:gp2

#   ifdef LABEL_CN
  d16 pl12:f2 pl16:f3

  4u BLKGRAD
  go=2 ph31 cpd2:f2 cpd3:f3
  d1 do:f2 do:f3 mc #0 to 2 F1PH(calph(ph1, +90) & calph(ph7, +90), caldel(d0, +in0))
#   else
  d16

  4u BLKGRAD
  go=2 ph31
  d1 mc #0 to 2 F1PH(calph(ph1, +90) & calph(ph7, +90), caldel(d0, +in0))
#   endif /*LABEL_CN*/

exit


ph1=0 2 
ph2=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph3=2 2 0 0 1 1 3 3
ph4=0 0 2 2 3 3 1 1
ph5=1
ph6=3
ph7=2 0
ph8=2 2 2 2 2 2 2 2 0 0 0 0 0 0 0 0
ph9=1 1 1 1 1 1 1 1 3 3 3 3 3 3 3 3
ph31=0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;sp1 : f1 channel - shaped pulse  90 degree  (H2O on resonance)
;sp11: f1 channel - shaped pulse  90 degree  (H2O on resonance)
;sp13: f2 channel - shaped pulse 180 degree (adiabatic)
;spnam13: Crp60,0.5,20.1
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p8 : f2 channel - 180 degree shaped pulse for inversion (adiabatic)
;     = 500usec for Crp60,0.5,20.1
;p11: f1 channel -  90 degree shaped pulse
;p16: homospoil/gradient pulse
;p22: f3 channel - 180 degree high power pulse
;p29: f1 channel -  90 degree shaped pulse
;d0 : incremented delay (2D) = in0/2-p1*2/3.1416 or 3u
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d12: delay for power switching                      [20 usec]
;d16: delay for homospoil/gradient recovery
;inf1: 1/SW = 2 * DW
;in0: 1/(2 * SW) = DW
;nd0: 2
;ns: 8 * n
;ds: 16
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEQ


;use gradient ratio:    gp 1 : gp 2
;                         50 :   30

;for z-only gradients:
;gpz1: 50%
;gpz2: 30%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100


;Processing

;PHC0(F1): 90
;PHC1(F1): -180
;FCOR(F1): 1

;or with -DLABEL_CN
;PHC0(F1): 0
;PHC1(F1): 0
;FCOR(F1): 0.5


                                          ;preprocessor-flags-start
;LABEL_CN: for C-13 and N-15 labeled samples start experiment with 
;             option -DLABEL_CN (eda: ZGOPTNS)
                                          ;preprocessor-flags-end



;$Id: noesyfpgpphwg,v 1.12 2012/01/31 17:49:27 ber Exp $
