;cosyphpr
;avance-version (12/01/11)
;2D homonuclear shift correlation
;with presaturation during relaxation delay
;phase sensitive
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>


"d11=30m"
"d12=20u"
"d13=4u"


"in0=inf1"

"d0=in0/2-p1*2/3.1416-p0*2/3.1416"


1 ze
2 d11
3 d12 pl9:f1
  d1 cw:f1 ph29
  d13 do:f1
  d12 pl1:f1
  p1 ph1
  d0
  p0 ph2
  go=2 ph31
  d11 mc #0 to 2 F1PH(calph(ph1, +90) & calph(ph29, +90), caldel(d0, +in0))
exit


ph1=0 2 2 0 1 3 3 1
ph2=0 2 0 2 1 3 1 3
ph29=0
ph31=0 2 2 0 1 3 3 1


;pl1 : f1 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;p0 : f1 channel -  20 to 90 degree high power pulse
;p1 : f1 channel -  90 degree high power pulse
;d0 : incremented delay (2D)
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [4 usec]
;inf1: 1/SW = 2 * DW
;in0: 1/(1 * SW) = 2 * DW
;nd0: 1
;ns: 4 * n
;ds: 16
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEQ


;Processing

;PHC0(F1): 90
;PHC1(F1): -180
;FCOR(F1): 1



;$Id: cosyphpr,v 1.10 2012/01/31 17:49:22 ber Exp $
