;noesyfpgpph19
;avance-version (12/01/11)
;2D homonuclear correlation via dipolar coupling 
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive
;water suppression using 3-9-19 pulse sequence with gradients
;using flip-back pulse
;
;M. Piotto, V. Saudek & V. Sklenar, J. Biomol. NMR 2,
;   661 - 666 (1992)
;V. Sklenar, M. Piotto, R. Leppik & V. Saudek, J. Magn. Reson. A102,
;   241 -245 (1993)
;G. Lippens, C. Dhalluin & J.-M. Wieruszeski, J. Biomol. NMR 5,
;   327-331 (1995)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"d12=20u"


"in0=inf1"

"d0=in0/2-p1*4/3.1416"


"DELTA=d8-p16-d16-p11-d12-54u"

"TAU=p1*2/3.1416-(p0-p27)*0.231-de+46u"


"acqt0=0"
baseopt_echo


1 ze
2 d1
3 d12 pl1:f1
  p1 ph1
  d0
  p1 ph2
  DELTA 
  50u UNBLKGRAD
  p16:gp1
  d16 pl0:f1
  (p11:sp1 ph3:r):f1
  4u
  d12 pl1:f1
  p1 ph4
  50u pl18:f1
  p16:gp2
  d16
  p27*0.231 ph5
  d19*2
  p27*0.692 ph5
  d19*2
  p27*1.462 ph5
  d19*2
  p27*1.462 ph6
  d19*2
  p27*0.692 ph6
  d19*2
  p0*0.231 ph6
  TAU
  p16:gp2
  d16
  4u BLKGRAD
  go=2 ph31
  d1 mc #0 to 2 F1PH(calph(ph1, +90), caldel(d0, +in0))
exit


ph1=0 2 
ph2=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph3=2 2 0 0 1 1 3 3
ph4=0 0 2 2 3 3 1 1
ph5=0
ph6=2
ph31=0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3


;pl0 : 0W
;pl1 : f1 channel - power level for pulse (default)
;pl18: f1 channel - power level for 3-9-19-pulse (watergate)
;sp1: f1 channel - shaped pulse  90 degree
;p0 : f1 channel -  90 degree pulse at pl18
;                      use for fine adjustment
;p1 : f1 channel -  90 degree high power pulse
;p11: f1 channel -  90 degree shaped pulse
;p16: homospoil/gradient pulse
;p27: f1 channel -  90 degree pulse at pl18
;d0 : incremented delay (2D)
;d1 : relaxation delay; 1-5 * T1
;d8 : mixing time
;d12: delay for power switching                      [20 usec]
;d16: delay for homospoil/gradient recovery
;d19: delay for binomial water suppression
;     d19 = (1/(2*d)), d = distance of next null (in Hz)
;inf1: 1/SW = 2 * DW
;in0: 1/(1 * SW) = 2 * DW
;nd0: 1
;ns: 8 * n
;ds: 16
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEQ


;use gradient ratio:    gp 1 : gp 2
;                         50 :   30

;for z-only gradients:
;gpz1: 50%
;gpz2: 30%

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100


;Processing

;PHC0(F1): 90
;PHC1(F1): -180
;FCOR(F1): 1



;$Id: noesyfpgpph19,v 1.10 2012/01/31 17:49:27 ber Exp $
